为啥TW不能下载迅雷的链接？(页 1) - 旧版使用交流 - 2.x版本使用交流 - 世界之窗论坛

360439394 发表于 2008-6-6 08:46

为啥TW不能下载迅雷的链接？

迅雷的链接只是把一个网址加密了而已，没有什么验证程序说非迅雷不能下，用软件还原迅雷链接以后也可以用普通下载工具下载。

那么，为啥TW内建的下载器不能下载迅雷的链接？

360439394 发表于 2008-6-6 08:50

网上漫山遍野的破解网站

[url]http://www.x2y2.com/sites/Thunder/[/url]
[url]http://xl.zg99.com/JM.asp[/url]

还有工具，连源代码都有。
[url]http://hi.baidu.com/helfee/blog/item/7e0496ca74026785c917688d.html[/url]

#SingleInstance force
#NoTrayIcon
Chars=ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/
Gui,Add,Edit,w250 vurl ReadOnly,复制地址后，点【Encode/Decode】
Gui,Add,Button,w120,Encode/&Decode
Gui,Add,Button,w120 xp+130,&Cancel
Gui,Add,Edit,w250 vu1 ReadOnly x10
Gui,Add,Edit,w250 vu2 ReadOnly
Gui,Add,Edit,w250 vu3 ReadOnly
Gui,Show,w275 h60,迅雷/快车/旋风地址转换
Return

ButtonEncode/Decode:
GuiControlGet,url
IfNotEqual,url,%Clipboard%
{GuiControl,,edit1,% Clipboard
url:=Clipboard
}
RegExMatch(url,"(?<=^).+(?=://)",t)
RegExMatch(url,"(?<=://).+",m)
If t=thunder
RegExMatch(InvBase64(m),"(?<=^AA).+(?=ZZ)",url)
Else If t=flashget
RegExMatch(InvBase64(m),"(?<=FLASHGET.).+(?=.FLASHGET)",url)
Else If t=qqdl
url:=InvBase64(m)
Else IfEqual,t,
{Gui,Show,w275 h60
GuiControl,,edit1,错误地址!!!
return
}
Else Goto,Encode
Gui,Show,w275 h60
GuiControl,,url,%url%
Clipboard:=url
ControlFocus,edit1
ControlSend,edit1,^a
Return

Encode:
Gui,Show,w275 h140
GuiControl,,u1, % "Thunder://" Base64("AA" url "ZZ")
GuiControl,,u2, % "Flashget://" Base64("[FLASHGET]" url "[FLASHGET]")
GuiControl,,u3, % "Qqdl://" Base64(url)
Return

#IfWinActive,迅雷/快车/旋风地址转换 ahk_class AutoHotkeyGUI
~^LButton::
~LButton::
MouseGetPos,,,id,control
WinGetTitle,title,ahk_id %id%
StringTrimRight,control2,control,1
if (title="迅雷/快车/旋风地址转换" and control2="edit")
{ if control<>edit1
   {
      GuiControlGet,aa,,%control%
      ControlSend,%control%,^a,ahk_id %id%
      Clipboard:=aa
   }
}
Return
#IfWinActive

guiClose:
guiEscape:
ButtonCancel:
ExitApp

;From [url]http://www.autohotkey.com/forum/viewtopic.php?p=35427[/url]
Base64(string) {
Loop Parse,string
{
   If Mod(A_Index,3) = 1
      buffer := Asc(A_LoopField) << 16
   Else If Mod(A_Index,3) = 2
      buffer += Asc(A_LoopField) << 8
   Else {
      buffer += Asc(A_LoopField)
      out := out . Code(buffer>>18) . Code(buffer>>12) . Code(buffer>>6) . Code(buffer)
   }
}
If Mod(StrLen(string),3) = 0
   Return out
If Mod(StrLen(string),3) = 1
   Return out . Code(buffer>>18) . Code(buffer>>12) "=="
Return out . Code(buffer>>18) . Code(buffer>>12) . Code(buffer>>6) "="
}

InvBase64(code) {
StringReplace code,code,=,,All
Loop Parse,code
{
   If Mod(A_Index,4) = 1
      buffer := DeCode(A_LoopField) << 18
   Else If Mod(A_Index,4) = 2
      buffer += DeCode(A_LoopField) << 12
   Else If Mod(A_Index,4) = 3
      buffer += DeCode(A_LoopField) << 6
   Else {
      buffer += DeCode(A_LoopField)
      out := out . Chr(buffer>>16) . Chr(255 & buffer>>8) . Chr(255 & buffer)
   }
}
If Mod(StrLen(code),4) = 0
   Return out
If Mod(StrLen(code),4) = 2
   Return out . Chr(buffer>>16)
Return out . Chr(buffer>>16) . Chr(255 & buffer>>8)
}

Code(i) { ; <== Chars[i & 63],0-base index
Global Chars
StringMid i,Chars,(i&63)+1,1
Return i
}

DeCode(c) { ; c = a char in Chars ==> position [0,63]
Global Chars
Return InStr(Chars,c,1) - 1
}

lanjing512 发表于 2008-6-6 08:55

官方还是不要用破解链接的方式为好！！！

可以以个人插件的形式。。。。。。。。不然给人的感觉不正规，破解总是跟盗版连在一起

360439394 发表于 2008-6-6 08:58

现在有这个插件么？地址发上来。

phcole 发表于 2008-6-6 09:01

应该这么说
对于迅雷快车链的支持
tw官方是不可以加入的
支持它可以算属于逆向工程了
自己看看安装迅雷的时候的许可协议
否则会引起官方与迅雷的纠纷

这些所谓的破解属于民间行为
所以迅雷想管没办法
Ayu的修改版迅雷支持快车的链接最后也是迫于快车官方的压力而最后取消了支持

qiao7387 发表于 2008-6-6 15:26

停止对快车专用链支持
2007-08-21
即日起停止对Flashget专用链支持，以后的版本中将不再支持此项功能，具体原因不在此赘述。

btw：当迅雷不遗余力之时，ZCOM只有自食其力了。落后就要挨打，穷途只有危亡。快车，一路走好;-)

sirly 发表于 2010-11-22 21:59

[url=https://chrome.google.com/extensions]https://chrome.google.com/extensions[/url] [b][size=7]自己去搜吧哈哈哈什么都有[/size][/b]

页: [1]

世界之窗论坛's Archiver

为啥TW不能下载迅雷的链接？